'startbanner.vbs - Enable/Disable the Click Here to Begin Banner
'© Doug Knox - rev 12/03/99

Option Explicit
On Error Resume Next

'Declare variables
Dim WSHShell, n, MyBox, p, p1, p2, t, mustboot, errnum, vers
Dim update1, update2, update3, update4, urladdr, itemtype
Dim enab, disab, jobfunc

Set WSHShell = WScript.CreateObject("WScript.Shell")
update1 = "Version 5.1 of VB Script and Version 2.0" & vbCR
update2 = "of Windows Scripting Host are recommended." & vbCR
update3 = "Would you like to download them now?"
update4 = update1 & update2 & update3
urladdr = "http://msdn.microsoft.com/scripting"
p = "HKCU\Software\Microsoft\Windows\CurrentVersion\Policies\Explorer\"
p1 = "NoStartBanner"
p2 = p  & p1
itemtype = "REG_DWORD"
mustboot = "Log off and back on, or restart your pc to" & vbCR & "effect the changes"
enab = "ENABLED"
disab = "DISABLED"
jobfunc = "The Start Button Banner is now "

'Check WSH Version. If earlier than 5.1 display dialog and ask if
'user wants to go to Scripting Page.
vers = WScript.Version
t = "WSH Version check"
If vers < 5.1 Then
MyBox = MsgBox(update4 , 4161, t)
	If MyBox = vbCancel Then
	    WScript.Quit
	ElseIf MyBox = vbOK Then
	    WSHShell.Run (urladdr)
	    WScript.Quit
	End If
End If

'This section tries to read the registry key value. If not present an 
'error is generated.  Normal error return should be 0 if value is 
'present
t = "Confirmation"
Err.Clear
n = WSHShell.RegRead (p2)
errnum = Err.Number

if errnum <> 0 then
'Create the registry key value for NoStartBanner with value 0
	WSHShell.RegWrite p2, 0, itemtype
End If

'If the key is present, or was created, it is toggled
'Confirmations can be disabled by commenting out 
'the two MyBox lines below

If n = 0 Then
	n = 1
WSHShell.RegWrite p2, n, itemtype
Mybox = MsgBox(jobfunc & disab & vbCR & mustboot, 4096, t)
ElseIf n = 1 then
	n = 0
WSHShell.RegWrite p2, n, itemtype
Mybox = MsgBox(jobfunc & enab & vbCR & mustboot, 4096, t)
End If